Remove all single characters from string using xslt1.0

Question

<title>
 <article_title>Land a b   c   d      Band</article_title>
</title>

using the following function

replace(article_title, '(^[^ ]+)(.+\s+)([^ ]+)$', '$1 $3')

this string in is transformed to Land Band which is exactly what i want.

but the problem is i need this solution in xslt 1.0 since the java app that i am working with can only handle xslt 1.0 parsing.

Dimitre Novatchev · Accepted Answer · 2012-02-01 05:52:36Z

1

This XSLT 1.0 transformation (there is a nasty SO bug and the code isn't indented -- I apologize for this visual mess...):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()" name="removeSingles">
   <xsl:param name="pText" select="."/>

   <xsl:variable name="vText" select="normalize-space($pText)"/>

   <xsl:if test="string-length($vText)">
    <xsl:variable name="vLeftChars" select=
    "substring-before(concat($vText, ' '), ' ')"/>

    <xsl:if test="string-length($vLeftChars) >1">
     <xsl:value-of select="$vLeftChars"/>
     <xsl:if test=
      "not(string-length($vLeftChars)
          >=
           string-length($vText)
           )
      ">
       <xsl:text> </xsl:text>
      </xsl:if>
    </xsl:if>

    <xsl:call-template name="removeSingles">
     <xsl:with-param name="pText" select=
     "substring-after($vText, ' ')"/>
    </xsl:call-template>
   </xsl:if>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<title>
 <article_title>Land a b   c   d      Band</article_title>
</title>

produces the wanted, correct result:

<title>
   <article_title>Land Band</article_title>
</title>

answered Feb 1, 2012 at 5:52

Dimitre Novatchev

244k27 gold badges308 silver badges438 bronze badges

Sign up to request clarification or add additional context in comments.

8 Comments

sanjay Over a year ago

Dimitre, thanks looks like it should work, how do i call this ? is this correct <xsl:value-of select="removeSingles"/>

Dimitre Novatchev Over a year ago

@sanjay: What do you mean by "Its not working". I always test my answers before publishing them. Just run the transformation on the provided XML document and you should get the reported result. If not, then either you modified the XSLT code, or you modified the XML file, or both, or your XSLT processor is buggy / not fully compliant.

sanjay Over a year ago

Dimitre, I really appreciate your effort and time, I have to apply this only to a particular element on my xml. This is how i am calling <xsl:value-of select="removeSingles"/> is this correct ?

Dimitre Novatchev Over a year ago

@sanjay: No, you need to: <xsl:call-template name="removeSingles"> <xsl:with-param name="pText" select="yourElement"/></xsl:call-template> . Also, remove the match="text()" from the removeSingles xsl:template instruction.

sanjay Over a year ago

Dimitri, Thank you very much.....it working. In your previous comment u asked me to remove match="text()" How do i do that and what will be the benefit ?

|

Collectives™ on Stack Overflow

Remove all single characters from string using xslt1.0

1 Answer 1

8 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

8 Comments

Your Answer

Sign up or log in

Post as a guest

Related