Importing from Outlook summary to Excel

Try like this maybe:

Public Function DateFromOutlook(myDate As String) As Date 'return an actual date...
    Dim dtpart As String, arr
    
    If myDate Like "#*/#*/####" Then ' 1 Old files - dd/mm/yyyy
        arr = Split(myDate, "/")
        DateFromOutlook = DateSerial(arr(2), arr(1), arr(0))
    ElseIf HowManyOfThese(myDate, "/") = 1 Then ' 2 This week - ddd dd/mm
        dtpart = Split(myDate, " ")(1) 'drop the day name
        DateFromOutlook = DateSerial(Year(Date), Right(dtpart, 2), Left(dtpart, 2))
    ElseIf HowManyOfThese(myDate, ":") = 1 Then ' 3 Today - ddd hh:mm
        DateFromOutlook = Date 'use today's date
    Else
        DateFromOutlook = CVErr(xlErrNA) 'catch-all for unmatched formats
    End If
End Function

Function HowManyOfThese(strVal, c As String) As Long
    HowManyOfThese = Len(strVal) - Len(Replace(strVal, c, ""))
End Function

EDIT: this is not much more code, doesn't need any date re-processing, and will handle subfolders. Needs a VBA reference to the outlook library.

Sub Main()
    Const PROCESS_SUBFOLDERS As Boolean = True
    Dim myolApp As Outlook.Application, objNS As Outlook.Namespace
    Dim objFolder As Outlook.Folder
    Set myolApp = GetObject(, "Outlook.Application") 'outlook must be open...
    Dim c As Range
    
    Set objNS = myolApp.GetNamespace("MAPI")
    MsgBox "Select the folder you want to create a listin for", _
            vbInformation

    'The listing in Excel will begin at cell `c`
    Set c = Selection '<< or use some specific location
    
    Set objFolder = objNS.PickFolder  'select the folder to list out
    If Not objFolder Is Nothing Then
        ProcessFolder objFolder, c, PROCESS_SUBFOLDERS, objFolder.Name
        MsgBox "Transfer Complete!"
    Else
        MsgBox "Outlook folder selection cancelled!"
    End If
    Application.StatusBar = False
End Sub

Sub ProcessFolder(StartFolder As Outlook.MAPIFolder, c As Range, _
                  doSubFolders As Boolean, Optional sfPath As String = "")
    Dim objItem As Object, objFolder As Outlook.Folder
        
    Application.StatusBar = "Processing " & StartFolder
    
    ' process all the items in this folder
    For Each objItem In StartFolder.Items
        If TypeName(objItem) = "MailItem" Then
            c.Value = objItem.Sender
            c.Offset(0, 1).Value = objItem.ReceivedTime
            c.Offset(0, 2).Value = objItem.Subject
            c.Offset(0, 3).Value = sfPath
            c.Offset(0, 4).Value = Round(objItem.Size / 1024, 2) & "kb"
            Set c = c.Offset(1)    'new row down
        End If
    Next
    
    ' process any subfolders of this folder?
    If doSubFolders Then
        For Each objFolder In StartFolder.Folders
            sfPath = sfPath & "/" & objFolder.Name 'append to the path
            ProcessFolder objFolder, c, doSubFolders, (sfPath) 'sfPath is passed by value
        Next
    End If
End Sub

This can also be accomplished using Power Query, available in Windows Excel 2010+ and Microsoft 365 (Windows or Mac). Power Query can interpret all of those date strings as dates except for the time.

To use Power Query

• Select some cell in your Data Table
• Data => Get&Transform => from Table/Range
• When the PQ Editor opens: Home => Advanced Editor
• Make note of the Table Name in Line 2
• Paste the M Code below in place of what you see
• Change the Table name in line 2 back to what was generated originally.
• Read the comments and explore the Applied Steps to understand the algorithm

let

//Change Table Name to your actual table name
    Source = Excel.CurrentWorkbook(){[Name="Table2"]}[Content],

//Set the data types
//PQ will interpret the information as dates except for the entry that is only a Time
    #"Changed Type" = Table.TransformColumnTypes(Source,{
        {"From", type text}, {"Subject", type text}, {"Received", type date}, {"Size", type text}},"en-150"),

//The "time" entry returns an error, so we replace it with today's date
    #"Replace Error" = Table.ReplaceErrorValues(#"Changed Type",{"Received", Date.From(DateTime.FixedLocalNow())})
in
    #"Replace Error"