Excel statistics for subtotal table values

Recommend shedding the SUBTOTAL function for the AGGREGATE function. You can program it to filter out all hidden rows. So, if you filter your dates, then filter out the zeros, it should give you what you want. Just be careful when you filter out zeroes for either meals or reflections, the filter may hide some non-zero rows for the other. I recommend building two separate sheets for both data. Picture shows the stats with dates filtered to 2025 and reflection count with zeroes filtered out.

=AGGREGATE(VSTACK(4,5,1,12,13), 5, C9:C423)

=AGGREGATE(VSTACK(4,5,1,12,13), 5, D9:D423)

You don't show what you want for an output, but here is one way using a single formula (uses 365 functions) which outputs the results in an array:

=LET(
    d, A2:D416,
    dates, CHOOSECOLS(d, 2),
    filter, FILTER(d, (dates >= Start_Date) * (dates <= End_Date)),
    RC, CHOOSECOLS(filter, 3),
    MC, CHOOSECOLS(filter, 4),
    RC_0, FILTER(RC, RC <> 0),
    MC_0, FILTER(MC, MC <> 0),
    stats, MAKEARRAY(
        5,
        4,
        LAMBDA(r, c,
            IF(
                c = 1,
                IFS(
                    r = 1,
                    MIN(RC),
                    r = 2,
                    MAX(RC),
                    r = 3,
                    AVERAGE(RC),
                    r = 4,
                    MEDIAN(RC),
                    r = 5,
                    MODE(RC)
                ),
                IF(
                    c = 2,
                    IFS(
                        r = 1,
                        MIN(MC),
                        r = 2,
                        MAX(MC),
                        r = 3,
                        AVERAGE(MC),
                        r = 4,
                        MEDIAN(MC),
                        r = 5,
                        MODE(MC)
                    ),
                    IF(
                        c = 3,
                        IFS(
                            r = 1,
                            MIN(RC_0),
                            r = 2,
                            MAX(RC_0),
                            r = 3,
                            AVERAGE(RC_0),
                            r = 4,
                            MEDIAN(RC_0),
                            r = 5,
                            MODE(RC_0)
                        ),
                        IF(
                            c = 4,
                            IFS(
                                r = 1,
                                MIN(MC_0),
                                r = 2,
                                MAX(MC_0),
                                r = 3,
                                AVERAGE(MC_0),
                                r = 4,
                                MEDIAN(MC_0),
                                r = 5,
                                MODE(MC_0)
                            )
                        )
                    )
                )
            )
        )
    ),
    rwHdrs, {"MIN"; "MAX"; "MEAN"; "MEDIAN"; "MODE"},
    colHdrs, {"Stat", "RC", "MC", "RC~0", "MC~0"},
    VSTACK(colHdrs, HSTACK(rwHdrs, stats))
)

Given the data you posted, and the filter parameters seen in the screenshot, this is the output:

(The first pair of columns includes all the data; the second pair excludes zero's)