Plot only interaction terms in coefplot

Question

After a regression in Stata, I am trying to plot only the coefficients of the interaction terms.

I was unable to do this using the community-contributed command coefplot.

Here is a reproducible example and my attempted solutions:

sysuse auto, clear
reg price foreign i.turn foreign#i.turn

*this plots all coefficients:
coefplot,

*this drops _cons and foreign but not i.turn
coefplot, drop(i.turn _cons foreign )

*variations with keep also do not work
coefplot, keep(foreign#i.turn )

Is there any other way to to this?

I have cross-posted this question on Statalist.

score 6 · Accepted Answer · 2018-07-23 18:53:36Z

6

You just need to specify the interactions:

sysuse auto, clear

reg price foreign i.turn foreign#i.turn, coeflegend noheader

local coefinter 1.foreign#33.turn 1.foreign#34.turn 1.foreign#35.turn ///
                1.foreign#36.turn 1.foreign#37.turn

coefplot, keep(`coefinter')

EDIT:

You can also get all non-zero coefficients as follows:

sysuse auto, clear
reg price foreign i.turn i.foreign#i.turn, coeflegend noheader

matrix A = e(b)
local namecol "`: colnames A'"

tokenize `namecol'

forvalues i = 1 / `=colsof(matrix(A))' {
    local mv = A[1,`i']
    if `mv' != 0 & strmatch("``i''" , "*#*") {
        local coefinter `coefinter' ``i''
    }
}

coefplot, keep(`coefinter')

edited Jul 23, 2018 at 18:53

answered Jul 23, 2018 at 18:35

user8682794

Sign up to request clarification or add additional context in comments.

3 Comments

user8682794 Over a year ago

By the way, after regress you can also use margins 1.foreign#i.turn and then marginsplot to get the same graph.

LucasMation Over a year ago

do you envision a more automatic way to list the coefficients? I have several res, each of which is saved with eststo. I have 108 time periods, which get interacted with the treatment variable

user8682794 Over a year ago

It is not clear to me from your comment what you have. I think you may want to post a new question about this providing more details.

Alberto Montoya · Accepted Answer · 2021-04-12 12:25:15Z

5

A solution a little bit easier than the one already proposed is to use wildcards ("*" or "?").

sysuse auto, clear
reg price foreign i.turn foreign#i.turn
coefplot, keep(*.foreign#*.turn)

answered Apr 12, 2021 at 12:25

Alberto Montoya

511 silver badge1 bronze badge

Collectives™ on Stack Overflow

Plot only interaction terms in coefplot

2 Answers 2

3 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related