Remove parent node if child node is empty

Question

I am trying to transform a given XML using xslt. The caveat is that I would have to delete a parent node if a given child node is not present. I did do some template matching, but I am stuck. Any help would be appreciated.

The input xml :

<?xml version="1.0" encoding="UTF-8"?>
<main>
     <item>
        <value>
           <item>
              <value>ABC</value>
              <key>test1</key>
           </item>
           <item>
              <value>XYZ</value>
              <key>test2</key>
           </item>
               <item>
              <value></value>
              <key>test3</key>
           </item>
        </value>
     </item>
     <item>
        <value />
        <key>test4</key>
     </item>
     <item>
        <value>PQR</value>
        <key>test5</key>
     </item>
</main>

Expected Output:

<?xml version="1.0" encoding="UTF-8"?>
<main>
     <item>
        <value>
           <item>
              <value>ABC</value>
              <key>test1</key>
           </item>
           <item>
              <value>XYZ</value>
              <key>test2</key>
           </item>
        </value>
     </item>
     <item>
        <value>PQR</value>
        <key>test5</key>
     </item>
</main>

The issue is if I use template matching e.g.

<xsl:template match="item[not(value)]"/> as mentioned in deleting the parent node if child node is not present in xml using xslt, then it completely removes everything as main/item/value is also empty.

What I need is remove if element is empty but only do if element has no child element.

Additionally if value for key test1 and test2 is empty then top level item element should also be excluded from output. — Ady211
– Ady211, Commented Jul 20, 2016 at 1:23

Tim C · Accepted Answer · 2016-07-20 07:57:18Z

1

You should first start with the XSLT identity template

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

Then, all you need is a template that matches the item element where all descendent leaf value elements are empty.

 <xsl:template match="item[not(descendant::value[not(*)][normalize-space()])]" />

So, the template matches it, but doesn't output it.

Try this XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="item[not(descendant::value[not(*)][normalize-space()])]" />

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

edited Jul 20, 2016 at 7:57

answered Jul 20, 2016 at 7:50

Tim C

70.7k14 gold badges77 silver badges94 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Ady211 Over a year ago

This works like a charm. How does this xslt differentiate between main/item/value (which is empty and has child node item) against item/value? Is the not(*) doing the trick?

Tim C Over a year ago

Yes. Doing not(*) checks for a lack of child elements, so it will only match the "leaf" elements.

jdk · Accepted Answer · 2016-07-20 04:43:28Z

0

I think you want to remove the element of it has no children at all (whether those children be elements or text nodes). Try inserting this template:

<xsl:template match="item">
    <xsl:if test="exists(value/node())">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:if>
</xsl:template>

answered Jul 20, 2016 at 4:43

jdk

2192 silver badges7 bronze badges

3 Comments

Ady211 Over a year ago

I tried it's not working and giving xslt compilation error. Error:XSLTProcessor::transformToXml(): xmlXPathCompiledEval: 1 objects left on the stack.

michael.hor257k Over a year ago

@Ady211 Are you sure you are using XSLT 2.0, as the tag on your question indicates?

Ady211 Over a year ago

I am using xslt 1.0.

michael.hor257k · Accepted Answer · 2016-07-20 11:24:58Z

0

If I read this correctly, you want to do:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="item[not(value[node()])]"/>

</xsl:stylesheet>

This will remove any item that does not have a value child with some content.

edited Jul 20, 2016 at 11:24

answered Jul 20, 2016 at 11:19

michael.hor257k

118k6 gold badges36 silver badges55 bronze badges

Collectives™ on Stack Overflow

Remove parent node if child node is empty

3 Answers 3

2 Comments

3 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related