blob: 7c1ddb2609f8d7d7424c1a9b800de84ce65a4fd8 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_PN=GitPython
PYTHON_COMPAT=( python3_{12..15} python3_{14,15}t )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 pypi
TEST_P=GitPython-${PV}
GITDB_P=gitdb-4.0.12
SMMAP_P=smmap-5.0.1
DESCRIPTION="Library used to interact with Git repositories"
HOMEPAGE="
https://github.com/gitpython-developers/GitPython/
https://pypi.org/project/GitPython/
"
SRC_URI+="
test? (
https://distfiles.gentoo.org/pub/proj/python/GitPython/${TEST_P}.gitbundle
)
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
RDEPEND="
dev-vcs/git
>=dev-python/gitdb-4.0.1[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
>=dev-python/ddt-1.1.1[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=( pytest-mock )
distutils_enable_tests pytest
src_test() {
git config --global user.email "travis@ci.com" || die
git config --global user.name "Travis Runner" || die
git clone "${DISTDIR}/${TEST_P}.gitbundle" "${T}"/test || die
cd "${T}"/test || die
git rev-parse HEAD > .git/refs/remotes/origin/master || die
TRAVIS=1 ./init-tests-after-clone.sh || die
cat test/fixtures/.gitconfig >> ~/.gitconfig || die
distutils-r1_src_test
}
python_test() {
local EPYTEST_DESELECT=(
# performance tests are unreliable by design
test/performance
# unimportant and problematic
test/test_installation.py
# Internet
test/test_quick_doc.py::QuickDoc::test_cloned_repo_object
# TODO
test/test_submodule.py::TestSubmodule::test_base_rw
test/test_submodule.py::TestSubmodule::test_root_module
test/test_remote.py::TestTimeouts::test_timeout_funcs
)
epytest -o addopts= test
}
|
GitWeb
