forked from github/codeql
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathType.qll
More file actions
executable file
·1083 lines (957 loc) · 33.5 KB
/
Type.qll
File metadata and controls
executable file
·1083 lines (957 loc) · 33.5 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/**
* Provides classes and predicates for working with Java types.
*
* Types can be primitive types (`PrimitiveType`), array types (`Array`), or reference
* types (`RefType`), where the latter are either classes (`Class`) or interfaces
* (`Interface`).
*
* Reference types can be at the top level (`TopLevelType`) or nested (`NestedType`).
* Classes can also be local (`LocalClass`) or anonymous (`AnonymousClass`).
* Enumerated types (`EnumType`) are a special kind of class.
*/
import Member
import Modifier
import JDK
/**
* Holds if reference type `t` is an immediate super-type of `sub`.
*/
cached
predicate hasSubtype(RefType t, Type sub) {
// Direct subtype.
extendsReftype(sub, t) and t != sub
or
implInterface(sub, t)
or
// A parameterized type `T<A>` is a subtype of the corresponding raw type `T<>`.
parSubtypeRaw(t, sub) and t != sub
or
// Array subtyping is covariant.
arraySubtype(t, sub) and t != sub
or
// Type parameter containment for parameterized types.
parContainmentSubtype(t, sub) and t != sub
or
// Type variables are subtypes of their upper bounds.
typeVarSubtypeBound(t, sub) and t != sub
}
private predicate typeVarSubtypeBound(RefType t, TypeVariable tv) {
if tv.hasTypeBound() then t = tv.getATypeBound().getType() else t instanceof TypeObject
}
private predicate parSubtypeRaw(RefType t, ParameterizedType sub) {
t = sub.getErasure().(GenericType).getRawType()
}
private predicate arraySubtype(Array sup, Array sub) {
hasSubtype(sup.getComponentType(), sub.getComponentType())
}
/*
* `parContainmentSubtype(pt, psub)` is equivalent to:
* ```
* pt != psub and
* pt.getGenericType() = psub.getGenericType() and
* forex(int i | i in [0..pt.getNumberOfTypeArguments()-1] |
* typeArgumentContains(_, pt.getTypeArgument(i), psub.getTypeArgument(i), _)
* )
* ```
* For performance several transformations are made. First, the `forex` is
* written as a loop where `typeArgumentsContain(_, pt, psub, n)` encode that
* the `forex` holds for `i in [0..n]`. Second, the relation is split into two
* cases depending on whether `pt.getNumberOfTypeArguments()` is 1 or 2+, as
* this allows us to unroll the loop and collapse the first two iterations. The
* base case for `typeArgumentsContain` is therefore `n=1` and this allows an
* improved join order implemented by `contains01`.
*/
private predicate parContainmentSubtype(ParameterizedType pt, ParameterizedType psub) {
pt != psub and
typeArgumentsContain(_, pt, psub, pt.getNumberOfTypeArguments() - 1)
or
typeArgumentsContain0(_, pt, psub)
}
/**
* Gets the `index`-th type parameter of `t`, which is a parameterization of `g`.
*/
private RefType parameterisationTypeArgument(GenericType g, ParameterizedType t, int index) {
g = t.getGenericType() and
result = t.getTypeArgument(index)
}
private predicate varianceCandidate(ParameterizedType pt) {
pt.getATypeArgument() instanceof Wildcard
}
pragma[noinline]
private RefType parameterisationTypeArgumentVarianceCand(
GenericType g, ParameterizedType t, int index
) {
result = parameterisationTypeArgument(g, t, index) and
varianceCandidate(t)
}
/**
* Holds if every type argument of `s` (up to `n` with `n >= 1`) contains the
* corresponding type argument of `t`. Both `s` and `t` are constrained to
* being parameterizations of `g`.
*/
pragma[nomagic]
private predicate typeArgumentsContain(
GenericType g, ParameterizedType s, ParameterizedType t, int n
) {
contains01(g, s, t) and n = 1
or
contains(g, s, t, n) and
typeArgumentsContain(g, s, t, n - 1)
}
private predicate typeArgumentsContain0(
GenericType g, ParameterizedType sParm, ParameterizedType tParm
) {
exists(RefType s, RefType t |
containsAux0(g, tParm, s, t) and
s = parameterisationTypeArgument(g, sParm, 0) and
s != t
)
}
/**
* Holds if the `n`-th type argument of `sParm` contain the `n`-th type
* argument of `tParm` for both `n = 0` and `n = 1`, where both `sParm` and
* `tParm` are parameterizations of the same generic type `g`.
*
* This is equivalent to
* ```
* contains(g, sParm, tParm, 0) and
* contains(g, sParm, tParm, 1)
* ```
* except `contains` is restricted to only include `n >= 2`.
*/
private predicate contains01(GenericType g, ParameterizedType sParm, ParameterizedType tParm) {
exists(RefType s0, RefType t0, RefType s1, RefType t1 |
contains01Aux0(g, tParm, s0, t0, t1) and
contains01Aux1(g, sParm, s0, s1, t1)
)
}
pragma[nomagic]
private predicate contains01Aux0(
GenericType g, ParameterizedType tParm, RefType s0, RefType t0, RefType t1
) {
typeArgumentContains(g, s0, t0, 0) and
t0 = parameterisationTypeArgument(g, tParm, 0) and
t1 = parameterisationTypeArgument(g, tParm, 1)
}
pragma[nomagic]
private predicate contains01Aux1(
GenericType g, ParameterizedType sParm, RefType s0, RefType s1, RefType t1
) {
typeArgumentContains(g, s1, t1, 1) and
s0 = parameterisationTypeArgumentVarianceCand(g, sParm, 0) and
s1 = parameterisationTypeArgumentVarianceCand(g, sParm, 1)
}
pragma[nomagic]
private predicate containsAux0(GenericType g, ParameterizedType tParm, RefType s, RefType t) {
typeArgumentContains(g, s, t, 0) and
t = parameterisationTypeArgument(g, tParm, 0) and
g.getNumberOfTypeParameters() = 1
}
/**
* Holds if the `n`-th type argument of `sParm` contain the `n`-th type
* argument of `tParm`, where both `sParm` and `tParm` are parameterizations of
* the same generic type `g`. The index `n` is restricted to `n >= 2`, the
* cases `n < 2` are handled by `contains01`.
*
* See JLS 4.5.1, Type Arguments of Parameterized Types.
*/
private predicate contains(GenericType g, ParameterizedType sParm, ParameterizedType tParm, int n) {
exists(RefType s, RefType t |
containsAux(g, tParm, n, s, t) and
s = parameterisationTypeArgumentVarianceCand(g, sParm, n)
)
}
pragma[nomagic]
private predicate containsAux(GenericType g, ParameterizedType tParm, int n, RefType s, RefType t) {
typeArgumentContains(g, s, t, n) and
t = parameterisationTypeArgument(g, tParm, n) and
n >= 2
}
/**
* Holds if the type argument `s` contains the type argument `t`, where both
* type arguments occur as index `n` in an instantiation of `g`.
*/
pragma[noinline]
private predicate typeArgumentContains(GenericType g, RefType s, RefType t, int n) {
typeArgumentContainsAux2(g, s, t, n) and
s = parameterisationTypeArgumentVarianceCand(g, _, n)
}
pragma[nomagic]
private predicate typeArgumentContainsAux2(GenericType g, RefType s, RefType t, int n) {
typeArgumentContainsAux1(s, t, n) and
t = parameterisationTypeArgument(g, _, n)
}
/**
* Holds if the type argument `s` contains the type argument `t`, where both
* type arguments occur as index `n` in some parameterized types.
*
* See JLS 4.5.1, Type Arguments of Parameterized Types.
*/
private predicate typeArgumentContainsAux1(RefType s, RefType t, int n) {
exists(int i |
s = parameterisationTypeArgumentVarianceCand(_, _, i) and
t = parameterisationTypeArgument(_, _, n) and
i <= n and
n <= i
|
exists(RefType tUpperBound | tUpperBound = t.(Wildcard).getUpperBound().getType() |
// ? extends T <= ? extends S if T <: S
hasSubtypeStar(s.(Wildcard).getUpperBound().getType(), tUpperBound)
or
// ? extends T <= ?
s.(Wildcard).isUnconstrained()
)
or
exists(RefType tLowerBound | tLowerBound = t.(Wildcard).getLowerBound().getType() |
// ? super T <= ? super S if s <: T
hasSubtypeStar(tLowerBound, s.(Wildcard).getLowerBound().getType())
or
// ? super T <= ?
s.(Wildcard).isUnconstrained()
or
// ? super T <= ? extends Object
wildcardExtendsObject(s)
)
or
// T <= T
s = t
or
// T <= ? extends T
hasSubtypeStar(s.(Wildcard).getUpperBound().getType(), t)
or
// T <= ? super T
hasSubtypeStar(t, s.(Wildcard).getLowerBound().getType())
)
}
pragma[noinline]
private predicate wildcardExtendsObject(Wildcard wc) {
wc.getUpperBound().getType() instanceof TypeObject
}
private predicate hasSubtypeStar(RefType t, RefType sub) {
sub = t
or
hasSubtype(t, sub)
or
exists(RefType mid | hasSubtypeStar(t, mid) and hasSubtype(mid, sub))
}
/** Holds if type `t` declares member `m`. */
predicate declaresMember(Type t, @member m) {
methods(m, _, _, _, t, _)
or
constrs(m, _, _, _, t, _)
or
fields(m, _, _, t, _)
or
enclInReftype(m, t) and
// Since the type `@member` in the dbscheme includes all `@reftype`s,
// anonymous and local classes need to be excluded here.
not m instanceof AnonymousClass and
not m instanceof LocalClass
}
/**
* A common abstraction for all Java types, including
* primitive, class, interface and array types.
*/
class Type extends Element, @type {
/**
* Gets the JVM descriptor for this type, as used in bytecode.
*/
string getTypeDescriptor() { none() }
/** Gets the erasure of this type. */
Type getErasure() { result = erase(this) }
}
/**
* An array type.
*
* Array types are implicitly declared when used; there is
* an array declaration for each array type used in the system.
*/
class Array extends RefType, @array {
/**
* Gets the type of the components of this array type.
*
* For example, the component type of `Object[][]` is `Object[]`.
*/
Type getComponentType() { arrays(this, _, _, _, result) }
/**
* Gets the type of the elements used to construct this array type.
*
* For example, the element type of `Object[][]` is `Object`.
*/
Type getElementType() { arrays(this, _, result, _, _) }
/**
* Gets the arity of this array type.
*
* For example, the dimension of `Object[][]` is 2.
*/
int getDimension() { arrays(this, _, _, result, _) }
/**
* Gets the JVM descriptor for this type, as used in bytecode.
*/
override string getTypeDescriptor() { result = "[" + this.getComponentType().getTypeDescriptor() }
}
/**
* A common super-class for various kinds of reference types,
* including classes, interfaces, type parameters and arrays.
*/
class RefType extends Type, Annotatable, Modifiable, @reftype {
/** Gets the package in which this type is declared. */
Package getPackage() {
classes(this, _, result, _) or
interfaces(this, _, result, _)
}
/** Gets the type in which this reference type is enclosed, if any. */
RefType getEnclosingType() { enclInReftype(this, result) }
/** Gets the compilation unit in which this type is declared. */
override CompilationUnit getCompilationUnit() { result = this.getFile() }
/** Holds if `t` is an immediate supertype of this type. */
predicate hasSupertype(RefType t) { hasSubtype(t, this) }
/** Holds if `t` is an immediate subtype of this type. */
predicate hasSubtype(RefType t) { hasSubtype(this, t) }
/** Gets a direct subtype of this type. */
RefType getASubtype() { hasSubtype(this, result) }
/** Gets a direct supertype of this type. */
RefType getASupertype() { hasSubtype(result, this) }
/** Gets a direct or indirect supertype of this type, including itself. */
RefType getAnAncestor() { hasSubtype*(result, this) }
/**
* Gets the source declaration of a direct supertype of this type, excluding itself.
*
* Note, that a generic type is the source declaration of a direct supertype
* of itself, namely the corresponding raw type, and this case is thus
* explicitly excluded. See also `getSourceDeclaration()`.
*/
pragma[noinline]
RefType getASourceSupertype() {
result = this.getASupertype().getSourceDeclaration() and
result != this
}
/**
* Holds if `t` is an immediate super-type of this type using only the immediate
* `extends` or `implements` relationships. In particular, this excludes
* parameter containment sub-typing for parameterized types.
*/
predicate extendsOrImplements(RefType t) {
extendsReftype(this, t) or
implInterface(this, t) or
typeVarSubtypeBound(t, this)
}
/** Holds if this type declares any members. */
predicate hasMember() { exists(getAMember()) }
/** Gets a member declared in this type. */
Member getAMember() { this = result.getDeclaringType() }
/** Gets a method declared in this type. */
Method getAMethod() { this = result.getDeclaringType() }
/** Gets a constructor declared in this type. */
Constructor getAConstructor() { this = result.getDeclaringType() }
/** Gets a method or constructor declared in this type. */
Callable getACallable() { this = result.getDeclaringType() }
/** Gets a field declared in this type. */
Field getAField() { this = result.getDeclaringType() }
/** Holds if this type declares a method with the specified name. */
predicate declaresMethod(string name) { this.getAMethod().getName() = name }
/** Holds if this type declares a method with the specified name and number of parameters. */
predicate declaresMethod(string name, int n) {
exists(Method m | m = this.getAMethod() |
m.getName() = name and
m.getNumberOfParameters() = n
)
}
/** Holds if this type declares a field with the specified name. */
predicate declaresField(string name) { this.getAField().getName() = name }
/** Gets the number of methods declared in this type. */
int getNumberOfMethods() { result = count(Method m | m.getDeclaringType() = this) }
/**
* Holds if this type declares or inherits method `m`, which is declared
* in `declaringType`.
*/
predicate hasMethod(Method m, RefType declaringType) { this.hasMethod(m, declaringType, false) }
/**
* Holds if this type declares or inherits method `m`, which is declared
* in `declaringType`. Methods that would be inherited if they were public,
* but are not inherited due to being package protected, are also included
* and indicated by `hidden` being true.
*/
cached
predicate hasMethod(Method m, RefType declaringType, boolean hidden) {
this.hasNonInterfaceMethod(m, declaringType, hidden)
or
this.hasInterfaceMethod(m, declaringType) and hidden = false
}
private predicate hasNonInterfaceMethod(Method m, RefType declaringType, boolean hidden) {
m = this.getAMethod() and
this = declaringType and
not declaringType instanceof Interface and
hidden = false
or
exists(RefType sup, boolean h1, boolean h2 |
(
if m.isPackageProtected() and sup.getPackage() != this.getPackage()
then h1 = true
else h1 = false
) and
(not sup instanceof Interface or this instanceof Interface) and
this.extendsOrImplements(sup) and
sup.hasNonInterfaceMethod(m, declaringType, h2) and
hidden = h1.booleanOr(h2) and
exists(string signature |
methods(m, _, signature, _, _, _) and not methods(_, _, signature, _, this, _)
) and
m.isInheritable()
)
}
private predicate cannotInheritInterfaceMethod(string signature) {
methods(_, _, signature, _, this, _)
or
exists(Method m | this.hasNonInterfaceMethod(m, _, false) and methods(m, _, signature, _, _, _))
}
private predicate interfaceMethodCandidateWithSignature(
Method m, string signature, RefType declaringType
) {
m = this.getAMethod() and
this = declaringType and
declaringType instanceof Interface and
methods(m, _, signature, _, _, _)
or
exists(RefType sup |
sup.interfaceMethodCandidateWithSignature(m, signature, declaringType) and
not this.cannotInheritInterfaceMethod(signature) and
this.extendsOrImplements(sup) and
m.isInheritable()
)
}
pragma[nomagic]
private predicate overrideEquivalentInterfaceMethodCandidates(Method m1, Method m2) {
exists(string signature |
this.interfaceMethodCandidateWithSignature(m1, signature, _) and
this.interfaceMethodCandidateWithSignature(m2, signature, _) and
m1 != m2 and
m2.overrides(_) and
any(Method m).overrides(m1)
)
}
pragma[noinline]
private predicate overriddenInterfaceMethodCandidate(Method m) {
exists(Method m2 |
this.overrideEquivalentInterfaceMethodCandidates(m, m2) and
m2.overrides(m)
)
}
private predicate hasInterfaceMethod(Method m, RefType declaringType) {
this.interfaceMethodCandidateWithSignature(m, _, declaringType) and
not this.overriddenInterfaceMethodCandidate(m)
}
/** Holds if this type declares or inherits the specified member. */
predicate inherits(Member m) {
exists(Field f | f = m |
f = this.getAField()
or
not f.isPrivate() and not this.declaresField(f.getName()) and this.getASupertype().inherits(f)
or
this.getSourceDeclaration().inherits(f)
)
or
this.hasMethod(m.(Method), _)
}
/** Holds if this is a top-level type, which is not nested inside any other types. */
predicate isTopLevel() { this instanceof TopLevelType }
/** Holds if this type is declared in a specified package with the specified name. */
predicate hasQualifiedName(string package, string type) {
this.getPackage().hasName(package) and type = this.nestedName()
}
/**
* Gets the JVM descriptor for this type, as used in bytecode.
*/
override string getTypeDescriptor() {
result =
"L" + this.getPackage().getName().replaceAll(".", "/") + "/" +
this.getSourceDeclaration().nestedName() + ";"
}
/**
* Gets the qualified name of this type.
*/
string getQualifiedName() {
exists(string pkgName | pkgName = getPackage().getName() |
if pkgName = "" then result = nestedName() else result = pkgName + "." + nestedName()
)
}
/** Gets the nested name of this type. */
string nestedName() {
not this instanceof NestedType and result = this.getName()
or
this.(NestedType).getEnclosingType().nestedName() + "$" + this.getName() = result
}
/**
* Gets the source declaration of this type.
*
* For parameterized instances of generic types and raw types, the
* source declaration is the corresponding generic type.
*
* For non-parameterized types declared inside a parameterized
* instance of a generic type, the source declaration is the
* corresponding type in the generic type.
*
* For all other types, the source declaration is the type itself.
*/
RefType getSourceDeclaration() { result = this }
/** Holds if this type is the same as its source declaration. */
predicate isSourceDeclaration() { this.getSourceDeclaration() = this }
/** Cast this reference type to a class that provides access to metrics information. */
MetricRefType getMetrics() { result = this }
/**
* A common (reflexive, transitive) subtype of the erasures of
* types `t1` and `t2`, if it exists.
*
* If there is no such common subtype, then the two types are disjoint.
* However, the converse is not true; for example, the parameterized types
* `List<Integer>` and `Collection<String>` are disjoint,
* but their erasures (`List` and `Collection`, respectively)
* do have common subtypes (such as `List` itself).
*
* For the definition of the notion of *erasure* see JLS v8, section 4.6 (Type Erasure).
*/
pragma[inline]
RefType commonSubtype(RefType other) {
result.getASourceSupertype*() = erase(this) and
result.getASourceSupertype*() = erase(other)
}
}
/** A type that is the same as its source declaration. */
class SrcRefType extends RefType {
SrcRefType() { this.isSourceDeclaration() }
}
/** A class declaration. */
class Class extends RefType, @class {
/** Holds if this class is an anonymous class. */
predicate isAnonymous() { isAnonymClass(this, _) }
/** Holds if this class is a local class. */
predicate isLocal() { isLocalClass(this, _) }
override RefType getSourceDeclaration() { classes(this, _, _, result) }
/**
* Gets an annotation that applies to this class.
*
* Note that a class may inherit annotations from super-classes.
*/
override Annotation getAnAnnotation() {
result = RefType.super.getAnAnnotation()
or
exists(AnnotationType tp | tp = result.getType() |
tp.isInherited() and
not exists(Annotation ann | ann = RefType.super.getAnAnnotation() | ann.getType() = tp) and
result = this.getASupertype().(Class).getAnAnnotation()
)
}
}
/**
* PREVIEW FEATURE in Java 14. Subject to removal in a future release.
*
* A record declaration.
*/
class Record extends Class {
Record() { isRecord(this) }
}
/** An intersection type. */
class IntersectionType extends RefType, @class {
IntersectionType() {
exists(string shortname |
classes(this, shortname, _, _) and
shortname.matches("% & ...")
)
}
private RefType superType() { extendsReftype(this, result) }
private RefType superInterface() { implInterface(this, result) }
/** Gets a textual representation of this type that includes all the intersected types. */
string getLongName() {
result = superType().toString() + concat(" & " + superInterface().toString())
}
/** Gets the first bound of this intersection type. */
RefType getFirstBound() { extendsReftype(this, result) }
}
/** An anonymous class. */
class AnonymousClass extends NestedClass {
AnonymousClass() { this.isAnonymous() }
/**
* Utility method: an integer that is larger for classes that
* are defined textually later.
*/
private int rankInParent(RefType parent) {
this.getEnclosingType() = parent and
exists(Location myLocation, File f, int maxCol | myLocation = this.getLocation() |
f = myLocation.getFile() and
maxCol = max(Location loc | loc.getFile() = f | loc.getStartColumn()) and
result = myLocation.getStartLine() * maxCol + myLocation.getStartColumn()
)
}
/**
* Gets the JVM descriptor for this type, as used in bytecode.
*
* For an anonymous class, the type descriptor is the descriptor of the
* enclosing type followed by a (1-based) counter of anonymous classes
* declared within that type.
*/
override string getTypeDescriptor() {
exists(RefType parent | parent = this.getEnclosingType() |
exists(int num |
num = 1 + count(AnonymousClass other | other.rankInParent(parent) < rankInParent(parent))
|
exists(string parentWithSemi | parentWithSemi = parent.getTypeDescriptor() |
result = parentWithSemi.prefix(parentWithSemi.length() - 1) + "$" + num + ";"
)
)
)
}
/** Gets the class instance expression where this anonymous class occurs. */
ClassInstanceExpr getClassInstanceExpr() { isAnonymClass(this, result) }
override string toString() {
result = "new " + this.getClassInstanceExpr().getTypeName() + "(...) { ... }"
}
/**
* Gets the qualified name of this type.
*
* Anonymous classes do not have qualified names, so we use
* the string `"<anonymous class>"` as a placeholder.
*/
override string getQualifiedName() { result = "<anonymous class>" }
}
/** A local class. */
class LocalClass extends NestedClass {
LocalClass() { this.isLocal() }
/** Gets the statement that declares this local class. */
LocalClassDeclStmt getLocalClassDeclStmt() { isLocalClass(this, result) }
}
/** A top-level type. */
class TopLevelType extends RefType {
TopLevelType() {
not enclInReftype(this, _) and
(this instanceof Class or this instanceof Interface)
}
}
/** A top-level class. */
class TopLevelClass extends TopLevelType, Class { }
/** A nested type is a type declared within another type. */
class NestedType extends RefType {
NestedType() { enclInReftype(this, _) }
/** Gets the type enclosing this nested type. */
override RefType getEnclosingType() { enclInReftype(this, result) }
/** Gets the nesting depth of this nested type. Top-level types have nesting depth 0. */
int getNestingDepth() {
if getEnclosingType() instanceof NestedType
then result = getEnclosingType().(NestedType).getNestingDepth() + 1
else result = 1
}
override predicate isPublic() {
super.isPublic()
or
// JLS 9.5: A member type declaration in an interface is implicitly public and static
exists(Interface i | this = i.getAMember())
}
override predicate isStrictfp() {
super.isStrictfp()
or
// JLS 8.1.1.3, JLS 9.1.1.2
getEnclosingType().isStrictfp()
}
/**
* Holds if this nested type is static.
*
* A nested type is static either if it is explicitly declared as such
* using the modifier `static`, or if it is implicitly static
* because one of the following holds:
*
* - it is a member type of an interface,
* - it is a member interface, or
* - it is a nested enum type.
*
* See JLS v8, section 8.5.1 (Static Member Type Declarations),
* section 8.9 (Enums) and section 9.5 (Member Type Declarations).
*/
override predicate isStatic() {
super.isStatic()
or
// JLS 8.5.1: A member interface is implicitly static.
this instanceof Interface
or
// JLS 8.9: A nested enum type is implicitly static.
this instanceof EnumType
or
// JLS 9.5: A member type declaration in an interface is implicitly public and static
exists(Interface i | this = i.getAMember())
}
}
/**
* A class declared within another type.
*
* This includes (static and non-static) member classes,
* local classes and anonymous classes.
*/
class NestedClass extends NestedType, Class { }
/**
* An inner class is a nested class that is neither
* explicitly nor implicitly declared static.
*/
class InnerClass extends NestedClass {
InnerClass() { not this.isStatic() }
/**
* Holds if an instance of this inner class holds a reference to its
* enclosing class.
*/
predicate hasEnclosingInstance() {
// JLS 15.9.2. Determining Enclosing Instances
not this.(AnonymousClass).getClassInstanceExpr().isInStaticContext() and
not this.(LocalClass).getLocalClassDeclStmt().getEnclosingCallable().isStatic()
}
}
/** An interface. */
class Interface extends RefType, @interface {
override RefType getSourceDeclaration() { interfaces(this, _, _, result) }
override predicate isAbstract() {
// JLS 9.1.1.1: "Every interface is implicitly abstract"
any()
}
}
/** A class or interface. */
class ClassOrInterface extends RefType {
ClassOrInterface() {
this instanceof Class or
this instanceof Interface
}
}
/**
* A primitive type.
*
* This includes `boolean`, `byte`, `short`,
* `char`, `int`, `long`, `float`,
* and `double`.
*/
class PrimitiveType extends Type, @primitive {
PrimitiveType() { this.getName().regexpMatch("float|double|int|boolean|short|byte|char|long") }
/** Gets the boxed type corresponding to this primitive type. */
BoxedType getBoxedType() { result.getPrimitiveType() = this }
/**
* Gets the JVM descriptor for this type, as used in bytecode.
*/
override string getTypeDescriptor() {
this.hasName("float") and result = "F"
or
this.hasName("double") and result = "D"
or
this.hasName("int") and result = "I"
or
this.hasName("boolean") and result = "Z"
or
this.hasName("short") and result = "S"
or
this.hasName("byte") and result = "B"
or
this.hasName("char") and result = "C"
or
this.hasName("long") and result = "J"
}
/**
* Gets a default value for this primitive type, as assigned by the compiler
* for variables that are declared but not initialized explicitly.
* Typically zero for numeric and character types and `false` for `boolean`.
*
* For numeric primitive types, default literals of one numeric type are also
* considered to be default values of all other numeric types, even if they
* require an explicit cast.
*/
Literal getADefaultValue() {
getName() = "boolean" and result.getLiteral() = "false"
or
getName() = "char" and
(result.getLiteral() = "'\\0'" or result.getLiteral() = "'\\u0000'")
or
getName().regexpMatch("(float|double|int|short|byte|long)") and
result.getLiteral().regexpMatch("0(\\.0)?+[lLfFdD]?+")
}
}
/** The type of the `null` literal. */
class NullType extends Type, @primitive {
NullType() { this.hasName("<nulltype>") }
}
/** The `void` type. */
class VoidType extends Type, @primitive {
VoidType() { this.hasName("void") }
/**
* Gets the JVM descriptor for this type, as used in bytecode.
*/
override string getTypeDescriptor() { result = "V" }
}
/**
* A boxed type.
*
* This includes `Boolean`, `Byte`, `Short`,
* `Character`, `Integer`, `Long`, `Float`,
* and `Double`.
*/
class BoxedType extends RefType {
BoxedType() {
this.hasQualifiedName("java.lang", "Float") or
this.hasQualifiedName("java.lang", "Double") or
this.hasQualifiedName("java.lang", "Integer") or
this.hasQualifiedName("java.lang", "Boolean") or
this.hasQualifiedName("java.lang", "Short") or
this.hasQualifiedName("java.lang", "Byte") or
this.hasQualifiedName("java.lang", "Character") or
this.hasQualifiedName("java.lang", "Long")
}
/** Gets the primitive type corresponding to this boxed type. */
PrimitiveType getPrimitiveType() {
this.hasName("Float") and result.hasName("float")
or
this.hasName("Double") and result.hasName("double")
or
this.hasName("Integer") and result.hasName("int")
or
this.hasName("Boolean") and result.hasName("boolean")
or
this.hasName("Short") and result.hasName("short")
or
this.hasName("Byte") and result.hasName("byte")
or
this.hasName("Character") and result.hasName("char")
or
this.hasName("Long") and result.hasName("long")
}
}
/**
* An enumerated type.
*
* Each enum type has zero or more enum constants which can
* be enumerated over.
* The type of an enum constant is the enum type itself.
*
* For example,
*
* ```
* enum X { A, B, C }
* ```
* is an enum type declaration, where the type of the enum
* constant `X.A` is `X`.
*/
class EnumType extends Class {
EnumType() { isEnumType(this) }
/** Gets the enum constant with the specified name. */
EnumConstant getEnumConstant(string name) {
fields(result, _, _, this, _) and result.hasName(name)
}
/** Gets an enum constant declared in this enum type. */
EnumConstant getAnEnumConstant() { fields(result, _, _, this, _) }
override predicate isFinal() {
// JLS 8.9: An enum declaration is implicitly `final` unless it contains
// at least one enum constant that has a class body.
not getAnEnumConstant().getAnAssignedValue().getType() instanceof AnonymousClass
}
}
/** An enum constant is a member of a enum type. */
class EnumConstant extends Field {
EnumConstant() { isEnumConst(this) }
// JLS 8.9.3: For each enum constant `c` in the body of the declaration of
// [enum type] `E`, `E` has an implicitly declared `public static final`
// field of type `E` that has the same name as `c`.
override predicate isPublic() { any() }
override predicate isStatic() { any() }
override predicate isFinal() { any() }
}
/**
* Gets the erasure of a type.
*
* See JLS v8, section 4.6 (Type Erasure).
*/
cached
private Type erase(Type t) {
result = t.(Class).getSourceDeclaration() and not t instanceof IntersectionType
or
result = erase(t.(IntersectionType).getFirstBound())
or
result = t.(Interface).getSourceDeclaration()
or
result.(Array).getComponentType() = erase(t.(Array).getComponentType())
or
result = erase(t.(BoundedType).getFirstUpperBoundType())
or
result = t.(NullType)
or
result = t.(VoidType)
or
result = t.(PrimitiveType)
}
/**
* Is there a common (reflexive, transitive) subtype of the erasures of