forked from taozhi8833998/node-sql-parser
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathdb2.pegjs
More file actions
1951 lines (1772 loc) · 46.3 KB
/
db2.pegjs
File metadata and controls
1951 lines (1772 loc) · 46.3 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{
const reservedMap = {
'ALTER': true,
'ALL': true,
'ADD': true,
'AND': true,
'AS': true,
'ASC': true,
'BETWEEN': true,
'BY': true,
'CALL': true,
'CASE': true,
'CREATE': true,
'CONTAINS': true,
'CURRENT_DATE': true,
'CURRENT_TIME': true,
'CURRENT_TIMESTAMP': true,
'CURRENT_USER': true,
'DELETE': true,
'DESC': true,
'DISTINCT': true,
'DROP': true,
'ELSE': true,
'END': true,
'EXISTS': true,
'EXCEPT': true,
'EXPLAIN': true,
'FALSE': true,
'FETCH': true,
'FROM': true,
'FULL': true,
'GROUP': true,
'HAVING': true,
'IN': true,
'INNER': true,
'INSERT': true,
'INTO': true,
'IS': true,
'JOIN': true,
'JSON': true,
'KEY': true,
'LEFT': true,
'LIKE': true,
'LIMIT': true,
'LOW_PRIORITY': true, // for lock table
'MINUS': true,
'NOT': true,
'NULL': true,
'OFFSET': true,
'ON': true,
'OR': true,
'ORDER': true,
'OUTER': true,
'RECURSIVE': true,
'RENAME': true,
'READ': true, // for lock table
'RIGHT': true,
'SELECT': true,
'SESSION_USER': true,
'SET': true,
'SHOW': true,
'SYSTEM_USER': true,
'TABLE': true,
'THEN': true,
'TRUE': true,
'TRUNCATE': true,
'TYPE': true, // reserved (MySQL)
'UNION': true,
'UPDATE': true,
'USING': true,
'VALUES': true,
'WITH': true,
'WHEN': true,
'WHERE': true,
'WRITE': true, // for lock table
'GLOBAL': true,
'SESSION': true,
'LOCAL': true,
'PERSIST': true,
'PERSIST_ONLY': true,
};
// Import common initializer functions and variables
@import 'common/initializer/functions.pegjs'
@import 'common/initializer/variables.pegjs'
}
start
= __ n:(multiple_stmt) {
return n
}
cmd_stmt
= drop_stmt
/ create_stmt
/ truncate_stmt
/ rename_stmt
/ call_stmt
/ use_stmt
/ alter_stmt
/ set_stmt
/ lock_stmt
/ unlock_stmt
/ declare_stmt
create_stmt
= create_table_stmt
/ create_db_stmt
alter_stmt
= alter_table_stmt
crud_stmt
= union_stmt
/ update_stmt
/ replace_insert_stmt
/ insert_no_columns_stmt
/ insert_into_set
/ delete_stmt
/ cmd_stmt
/ proc_stmts
multiple_stmt
= head:crud_stmt tail:(__ SEMICOLON __ crud_stmt)* {
const headAst = head && head.ast || head
const cur = tail && tail.length && tail[0].length >= 4 ? [headAst] : headAst;
for (let i = 0; i < tail.length; i++) {
if(!tail[i][3] || tail[i][3].length === 0) continue;
cur.push(tail[i][3] && tail[i][3].ast || tail[i][3]);
}
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: cur
}
}
set_op
= u:(KW_UNION / KW_INTERSECT / KW_EXCEPT) __ s:(KW_ALL / KW_DISTINCT)? {
return s ? `${u.toLowerCase()} ${s.toLowerCase()}` : `${u.toLowerCase()}`
}
/ KW_MINUS { return 'minus' }
union_stmt
= head:select_stmt tail:(__ set_op __ select_stmt)* __ ob: order_by_clause? __ l:limit_clause? {
let cur = head
for (let i = 0; i < tail.length; i++) {
cur._next = tail[i][3]
cur.set_op = tail[i][1]
cur = cur._next
}
if(ob) head._orderby = ob
if(l) head._limit = l
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: head
}
}
create_db_stmt
= a:KW_CREATE __
k:(KW_DATABASE / KW_SCHEMA) __
ife:if_not_exists_stmt? __
t:proc_func_name __
c:create_db_definition? {
const keyword = k.toLowerCase()
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: a[0].toLowerCase(),
keyword,
if_not_exists:ife,
[keyword]: { db: t.schema, schema: t.name },
create_definitions: c,
}
}
}
create_table_stmt
= a:KW_CREATE __
tp:KW_TEMPORARY? __
KW_TABLE __
ife:if_not_exists_stmt? __
t:table_ref_list __
c:create_table_definition __
to:table_options? __
ir: (KW_IGNORE / KW_REPLACE)? __
as: KW_AS? __
qe: union_stmt? {
if(t) t.forEach(tt => tableList.add(`create::${tt.db}::${tt.table}`));
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: a[0].toLowerCase(),
keyword: 'table',
temporary: tp && tp[0].toLowerCase(),
if_not_exists:ife,
table: t,
ignore_replace: ir && ir[0].toLowerCase(),
as: as && as[0].toLowerCase(),
query_expr: qe && qe.ast,
create_definitions: c,
table_options: to
}
}
}
/ a:KW_CREATE __
tp:KW_TEMPORARY? __
KW_TABLE __
ife:if_not_exists_stmt? __
t:table_ref_list __
lt:create_like_table {
if(t) t.forEach(tt => tableList.add(`create::${tt.db}::${tt.table}`));
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: a[0].toLowerCase(),
keyword: 'table',
temporary: tp && tp[0].toLowerCase(),
if_not_exists:ife,
table: t,
like: lt
}
}
}
create_definition
= create_constraint_definition
/ create_column_definition
/ create_index_definition
/ create_fulltext_spatial_index_definition
column_definition_opt
= n:(literal_not_null / literal_null) {
if (n && !n.value) n.value = 'null'
return { nullable: n }
}
/ d:default_expr {
return { default_val: d }
}
/ a:('AUTO_INCREMENT'i) {
return { auto_increment: a.toLowerCase() }
}
/ 'UNIQUE'i __ k:('KEY'i)? {
const sql = ['unique']
if (k) sql.push(k)
return { unique: sql.join(' ').toLowerCase('') }
}
/ p:('PRIMARY'i)? __ 'KEY'i {
const sql = []
if (p) sql.push('primary')
sql.push('key')
return { primary_key: sql.join(' ').toLowerCase('') }
}
/ co:keyword_comment {
return { comment: co }
}
/ ca:collate_expr {
return { collate: ca }
}
/ cf:column_format {
return { column_format: cf }
}
/ s:storage {
return { storage: s }
}
/ re:reference_definition {
return { reference_definition: re }
}
column_definition_opt_list
= head:column_definition_opt __ tail:(__ column_definition_opt)* {
let opt = head
for (let i = 0; i < tail.length; i++) {
opt = { ...opt, ...tail[i][1] }
}
return opt
}
create_column_definition
= c:column_ref __
d:data_type __
cdo:column_definition_opt_list? {
columnList.add(`create::${c.table}::${c.column}`)
return {
column: c,
definition: d,
resource: 'column',
...(cdo || {})
}
}
drop_index_opt
= head:(ALTER_ALGORITHM / ALTER_LOCK) tail:(__ (ALTER_ALGORITHM / ALTER_LOCK))* {
return createList(head, tail, 1)
}
drop_stmt
= a:KW_DROP __
r:KW_TABLE __
t:table_ref_list {
if(t) t.forEach(tt => tableList.add(`${a}::${tt.db}::${tt.table}`));
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: a.toLowerCase(),
keyword: r.toLowerCase(),
name: t
}
};
}
/ a:KW_DROP __
r:KW_INDEX __
i:column_ref __
KW_ON __
t:table_name __
op:drop_index_opt? __ {
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: a.toLowerCase(),
keyword: r.toLowerCase(),
name: i,
table: t,
options: op
}
};
}
truncate_stmt
= a:KW_TRUNCATE __
kw:KW_TABLE? __
t:table_ref_list {
if(t) t.forEach(tt => tableList.add(`${a}::${tt.db}::${tt.table}`));
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: a.toLowerCase(),
keyword: kw && kw.toLowerCase() || 'table',
name: t
}
};
}
use_stmt
= KW_USE __
d:ident {
tableList.add(`use::${d}::null`);
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'use',
db: d
}
};
}
// DB2 DECLARE GLOBAL TEMPORARY TABLE statement
declare_stmt
= KW_DECLARE __ KW_GLOBAL __ KW_TEMPORARY __ KW_TABLE __ t:table_name __
KW_AS __ LPAREN __ s:union_stmt __ RPAREN __
opts:declare_global_temp_table_opts? {
if (t) tableList.add(`declare::${t.db}::${t.table}`);
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'declare',
declare: [{
keyword: 'global temporary table',
name: t,
as: 'as',
prefix: 'global temporary table',
definition: s.ast,
definition_type: 'subquery',
...(opts || {})
}]
}
}
}
/ KW_DECLARE __ KW_GLOBAL __ KW_TEMPORARY __ KW_TABLE __ t:table_name __
c:create_table_definition __
opts:declare_global_temp_table_opts? {
if (t) tableList.add(`declare::${t.db}::${t.table}`);
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'declare',
declare: [{
keyword: 'global temporary table',
name: t,
prefix: 'global temporary table',
definition: c,
definition_type: 'columns',
...(opts || {})
}]
}
}
}
declare_global_temp_table_opts
= head:declare_global_temp_table_opt tail:(__ declare_global_temp_table_opt)* {
let result = head
for (let i = 0; i < tail.length; i++) {
result = { ...result, ...tail[i][1] }
}
return result
}
declare_global_temp_table_opt
= KW_WITH __ kw:('DATA'i / 'NO'i __ 'DATA'i) {
const value = Array.isArray(kw) ? kw.filter(k => k && k.trim()).join(' ') : kw
return { with_data: value.toLowerCase() }
}
/ KW_WITH __ 'REPLACE'i {
return { with_replace: 'replace' }
}
/ 'DEFINITION'i __ 'ONLY'i {
return { definition_only: 'definition only' }
}
/ KW_ON __ 'COMMIT'i __ action:('PRESERVE'i / 'DELETE'i) __ 'ROWS'i {
return { on_commit: `${action.toLowerCase()} rows` }
}
/ KW_ON __ 'ROLLBACK'i __ action:('PRESERVE'i / 'DELETE'i) __ 'ROWS'i {
return { on_rollback: `${action.toLowerCase()} rows` }
}
/ KW_NOT __ 'LOGGED'i {
return { not_logged: 'not logged' }
}
/ KW_IN __ ts:ident_name {
return { in_tablespace: ts }
}
alter_table_stmt
= KW_ALTER __
KW_TABLE __
t:table_ref_list __
e:alter_action_list {
if (t && t.length > 0) t.forEach(table => tableList.add(`alter::${table.db}::${table.table}`));
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'alter',
table: t,
expr: e
}
};
}
alter_action_list
= head:alter_action tail:(__ COMMA __ alter_action)* {
return createList(head, tail);
}
alter_action
= ALTER_ADD_CONSTRAINT
/ ALTER_DROP_CONSTRAINT
/ ALTER_ENABLE_CONSTRAINT
/ ALTER_DISABLE_CONSTRAINT
/ ALTER_ADD_COLUMN
/ ALTER_DROP_COLUMN
/ ALTER_ADD_INDEX_OR_KEY
/ ALTER_ADD_FULLETXT_SPARITAL_INDEX
/ ALTER_RENAME_TABLE
/ ALTER_ALGORITHM
/ ALTER_LOCK
ALTER_ADD_COLUMN
= KW_ADD __
kc:KW_COLUMN? __
cd:create_column_definition {
return {
action: 'add',
...cd,
keyword: kc,
resource: 'column',
type: 'alter',
}
}
ALTER_DROP_COLUMN
= KW_DROP __
kc:KW_COLUMN? __
c:column_ref {
return {
action: 'drop',
column: c,
keyword: kc,
resource: 'column',
type: 'alter',
}
}
ALTER_ADD_INDEX_OR_KEY
= KW_ADD __
id:create_index_definition
{
return {
action: 'add',
type: 'alter',
...id,
}
}
ALTER_RENAME_TABLE
= KW_RENAME __
kw:(KW_TO / KW_AS)? __
tn:ident {
return {
action: 'rename',
type: 'alter',
resource: 'table',
keyword: kw && kw[0].toLowerCase(),
table: tn
}
}
ALTER_ALGORITHM
= "ALGORITHM"i __ s:KW_ASSIGIN_EQUAL? __ val:("DEFAULT"i / "INSTANT"i / "INPLACE"i / "COPY"i) {
return {
type: 'alter',
keyword: 'algorithm',
resource: 'algorithm',
symbol: s,
algorithm: val
}
}
ALTER_LOCK
= "LOCK"i __ s:KW_ASSIGIN_EQUAL? __ val:("DEFAULT"i / "NONE"i / "SHARED"i / "EXCLUSIVE"i) {
return {
type: 'alter',
keyword: 'lock',
resource: 'lock',
symbol: s,
lock: val
}
}
ALTER_ADD_CONSTRAINT
= KW_ADD __ c:create_constraint_definition {
return {
action: 'add',
create_definitions: c,
resource: 'constraint',
type: 'alter',
}
}
ALTER_DROP_CONSTRAINT
= KW_DROP __ kc:'CHECK'i __ c:ident_name {
return {
action: 'drop',
constraint: c,
keyword: kc.toLowerCase(),
resource: 'constraint',
type: 'alter',
}
}
ALTER_ENABLE_CONSTRAINT
= KW_WITH __ 'CHECK'i __ 'CHECK'i __ KW_CONSTRAINT __ c:ident_name {
return {
action: 'with',
constraint: c,
keyword: 'check check',
resource: 'constraint',
type: 'alter',
}
}
ALTER_DISABLE_CONSTRAINT
= 'NOCHECK'i __ KW_CONSTRAINT __ c:ident_name {
return {
action: 'nocheck',
constraint: c,
resource: 'constraint',
type: 'alter',
}
}
create_constraint_definition
= create_constraint_primary
/ create_constraint_unique
/ create_constraint_foreign
/ create_constraint_check
create_constraint_primary
= kc:constraint_name? __
p:('PRIMARY KEY'i) __
t:index_type? __
de:cte_column_definition __
id:index_options? {
return {
constraint: kc && kc.constraint,
definition: de,
constraint_type: p.toLowerCase(),
keyword: kc && kc.keyword,
index_type: t,
resource: 'constraint',
index_options: id,
}
}
create_constraint_unique
= kc:constraint_name? __
u:KW_UNIQUE __
p:(KW_INDEX / KW_KEY)? __
i:column? __
t:index_type? __
de:cte_column_definition __
id:index_options? {
return {
constraint: kc && kc.constraint,
definition: de,
constraint_type: p && `${u.toLowerCase()} ${p.toLowerCase()}` || u.toLowerCase(),
keyword: kc && kc.keyword,
index_type: t,
index: i,
resource: 'constraint',
index_options: id
}
}
create_constraint_check
= kc:constraint_name? __ u:'CHECK'i __ nfr:('NOT'i __ 'FOR'i __ 'REPLICATION'i __)? LPAREN __ c:expr __ RPAREN {
return {
constraint_type: u.toLowerCase(),
keyword: kc && kc.keyword,
constraint: kc && kc.constraint,
index_type: nfr && { keyword: 'not for replication' },
definition: [c],
resource: 'constraint',
}
}
create_constraint_foreign
= kc:constraint_name? __
p:('FOREIGN KEY'i) __
i:column? __
de:cte_column_definition __
id:reference_definition? {
return {
constraint: kc && kc.constraint,
definition: de,
constraint_type: p,
keyword: kc && kc.keyword,
index: i,
resource: 'constraint',
reference_definition: id
}
}
ALTER_ADD_FULLETXT_SPARITAL_INDEX
= KW_ADD __ fsid:create_fulltext_spatial_index_definition {
return {
action: 'add',
type: 'alter',
...fsid,
}
}
rename_stmt
= KW_RENAME __
KW_TABLE __
t:table_to_list {
t.forEach(tg => tg.forEach(dt => dt.table && tableList.add(`rename::${dt.db}::${dt.table}`)))
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'rename',
table: t
}
};
}
set_stmt
= KW_SET __
kw: (KW_GLOBAL / KW_SESSION / KW_LOCAL / KW_PERSIST / KW_PERSIST_ONLY)? __
a: assign_stmt_list {
a.keyword = kw
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'set',
keyword: kw,
expr: a
}
}
}
unlock_stmt
= KW_UNLOCK __ KW_TABLES {
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'unlock',
keyword: 'tables'
}
}
}
lock_type
= "READ"i __ s:("LOCAL"i)? {
return {
type: 'read',
suffix: s && 'local'
}
}
/ p:("LOW_PRIORITY"i)? __ "WRITE"i {
return {
type: 'write',
prefix: p && 'low_priority'
}
}
lock_table
= t:table_base __ lt:lock_type {
tableList.add(`lock::${t.db}::${t.table}`)
return {
table: t,
lock_type: lt
}
}
lock_table_list
= head:lock_table tail:(__ COMMA __ lock_table)* {
return createList(head, tail);
}
lock_stmt
= KW_LOCK __ KW_TABLES __ ltl:lock_table_list {
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'lock',
keyword: 'tables',
tables: ltl
}
}
}
call_stmt
= KW_CALL __
e: proc_func_call {
return {
tableList: Array.from(tableList),
columnList: columnListTableAlias(columnList),
ast: {
type: 'call',
expr: e
}
}
}
select_stmt
= select_stmt_nake
/ s:('(' __ select_stmt __ ')') {
return {
...s[2],
parentheses_symbol: true,
}
}
with_clause
= KW_WITH __ head:cte_definition tail:(__ COMMA __ cte_definition)* {
return createList(head, tail);
}
/ __ KW_WITH __ KW_RECURSIVE __ cte:cte_definition tail:(__ COMMA __ cte_definition)* {
cte.recursive = true;
return createList(cte, tail);
}
cte_definition
= name:(literal_string / ident_name) __ columns:cte_column_definition? __ KW_AS __ LPAREN __ stmt:union_stmt __ RPAREN {
if (typeof name === 'string') name = { type: 'default', value: name }
return { name, stmt, columns };
}
cte_column_definition
= LPAREN __ l:column_ref_list __ RPAREN {
return l
}
select_stmt_nake
= __ cte:with_clause? __ KW_SELECT ___
opts:option_clause? __
d:KW_DISTINCT? __
c:column_clause __
f:from_clause? __
w:where_clause? __
g:group_by_clause? __
h:having_clause? __
o:order_by_clause? __
l:limit_clause?
iso:isolation_clause? __ {
if(f) f.forEach(info => info.table && tableList.add(`select::${info.db}::${info.table}`));
return {
with: cte,
type: 'select',
options: opts,
distinct: d,
columns: c,
from: f,
where: w,
groupby: g,
having: h,
orderby: o,
limit: l,
isolation: iso,
};
}
// MySQL extensions to standard SQL
option_clause
= head:query_option tail:(__ query_option)* {
const opts = [head];
for (let i = 0, l = tail.length; i < l; ++i) {
opts.push(tail[i][1]);
}
return opts;
}
query_option
= option:(
OPT_SQL_CALC_FOUND_ROWS
/ (OPT_SQL_CACHE / OPT_SQL_NO_CACHE)
/ OPT_SQL_BIG_RESULT
/ OPT_SQL_SMALL_RESULT
/ OPT_SQL_BUFFER_RESULT
) { return option; }
column_clause
= head: (KW_ALL / (STAR !ident_start) / STAR) tail:(__ COMMA __ column_list_item)* {
columnList.add('select::null::(.*)')
const item = {
expr: {
type: 'column_ref',
table: null,
column: '*'
},
as: null
}
if (tail && tail.length > 0) return createList(item, tail)
return [item]
}
/ head:column_list_item tail:(__ COMMA __ column_list_item)* {
return createList(head, tail);
}
column_list_item
= tbl:(ident __ DOT)? __ STAR {
const table = tbl && tbl[0] || null
columnList.add(`select::${table}::(.*)`);
return {
expr: {
type: 'column_ref',
table: table,
column: '*'
},
as: null
};
}
/ e:binary_column_expr __ alias:alias_clause? {
if (e.type === 'double_quote_string' || e.type === 'single_quote_string') {
columnList.add(`select::null::${e.value}`)
}
return { expr: e, as: alias };
}
alias_clause
= KW_AS __ i:alias_ident { return i; }
/ KW_AS? __ i:ident { return i; }
table_to_list
= head:table_to_item tail:(__ COMMA __ table_to_item)* {
return createList(head, tail);
}
table_to_item
= head:table_name __ KW_TO __ tail: (table_name) {
return [head, tail]
}
table_ref_list
= head:table_base
tail:table_ref* {
tail.unshift(head);
tail.forEach(tableInfo => {
const { table, as } = tableInfo
tableAlias[table] = table
if (as) tableAlias[as] = table
refreshColumnList(columnList)
})
return tail;
}
table_ref
= __ COMMA __ t:table_base { return t; }
/ __ t:table_join { return t; }
table_join
= op:join_op __ t:table_base __ KW_USING __ LPAREN __ head:ident_without_kw_type tail:(__ COMMA __ ident_without_kw_type)* __ RPAREN {
t.join = op;
t.using = createList(head, tail);
return t;
}
/ op:join_op __ t:table_base __ expr:on_clause? {
t.join = op;
t.on = expr;
return t;
}
/ op:(join_op / set_op) __ LPAREN __ stmt:union_stmt __ RPAREN __ alias:alias_clause? __ expr:on_clause? {
stmt.parentheses = true;
return {
expr: stmt,
as: alias,
join: op,
on: expr
};
}
//NOTE that, the table assigned to `var` shouldn't write in `table_join`
table_base
= KW_DUAL {
return {
type: 'dual'
};
}
/ t:table_name __ alias:alias_clause? {
if (t.type === 'var') {
t.as = alias;
return t;
} else {
return {
db: t.db,
table: t.table,
as: alias
};
}
}
/ LPAREN __ stmt:union_stmt __ RPAREN __ alias:alias_clause? {
stmt.parentheses = true;
return {
expr: stmt,
as: alias
};
}
join_op
= KW_LEFT __ KW_OUTER? __ KW_JOIN { return 'LEFT JOIN'; }
/ KW_RIGHT __ KW_OUTER? __ KW_JOIN { return 'RIGHT JOIN'; }
/ KW_FULL __ KW_OUTER? __ KW_JOIN { return 'FULL JOIN'; }
/ (KW_INNER __)? KW_JOIN { return 'INNER JOIN'; }
table_name
= dt:ident tail:(__ DOT __ ident)? {
const obj = { db: null, table: dt };
if (tail !== null) {
obj.db = dt;
obj.table = tail[3];
}
return obj;
}
/ v:var_decl {
v.db = null;