rescript-react-native · Freddy03h · Mar 10, 2026 · Mar 10, 2026 · Mar 18, 2026 · Mar 18, 2026
diff --git a/src/elements/NativeElement.bs.js b/src/elements/NativeElement.bs.js
@@ -1,7 +1,10 @@
 'use strict';
 
+var DOMAPI$ReactNative = require("../types/DOMAPI.bs.js");
 var NativeMethods$ReactNative = require("./NativeMethods.bs.js");
 
 NativeMethods$ReactNative.Make({});
 
+DOMAPI$ReactNative.$$Element.Impl({});
+
 /*  Not a pure module */
diff --git a/src/elements/NativeElement.res b/src/elements/NativeElement.res
@@ -1,6 +1,10 @@
-type element
+type element = DOMAPI.element
 type ref = Ref.t<element>
 
 include NativeMethods.Make({
   type t = element
 })
+
+include DOMAPI.Element.Impl({
+  type t = element
+})
diff --git a/src/types/DOMAPI.bs.js b/src/types/DOMAPI.bs.js
@@ -0,0 +1,61 @@
+'use strict';
+
+
+var $$NodeList = {};
+
+var $$HTMLCollection = {};
+
+function Impl(T) {
+  return {};
+}
+
+var $$Node = {
+  Impl: Impl
+};
+
+function Impl$1(T) {
+  return {};
+}
+
+var $$Element = {
+  Impl: Impl$1
+};
+
+var $$Document = {};
+
+var $$Text = {};
+
+function classify(node) {
+  switch (node.nodeType) {
+    case 1 :
+        return {
+                TAG: "Element",
+                _0: node
+              };
+    case 3 :
+        return {
+                TAG: "Text",
+                _0: node
+              };
+    case 9 :
+        return {
+                TAG: "Document",
+                _0: node
+              };
+    default:
+      return "Unknown";
+  }
+}
+
+var NodeType = {
+  classify: classify
+};
+
+exports.$$NodeList = $$NodeList;
+exports.$$HTMLCollection = $$HTMLCollection;
+exports.$$Node = $$Node;
+exports.$$Element = $$Element;
+exports.$$Document = $$Document;
+exports.$$Text = $$Text;
+exports.NodeType = NodeType;
+/* No side effect */
diff --git a/src/types/DOMAPI.res b/src/types/DOMAPI.res
@@ -0,0 +1,180 @@
+@@warning("-30")
+
+type nodeList<'node> = {length: int}
+type htmlCollection<'element> = {length: int}
+
+type readOnlyNode<'node, 'document, 'element> = {
+  // Node
+  childNodes: nodeList<'node>,
+  firstChild: Js.Null.t<'node>,
+  isConnected: bool,
+  lastChild: Js.Null.t<'node>,
+  nextSibling: Js.Null.t<'node>,
+  nodeType: int,
+  nodeName: string,
+  nodeValue: Js.Null.t<string>,
+  ownerDocument: Js.Null.t<'document>,
+  parentElement: Js.Null.t<'element>,
+  parentNode: Js.Null.t<'node>,
+  previousSibling: Js.Null.t<'node>,
+  textContent: string,
+}
+
+type rec node = {
+  ...readOnlyNode<node, document, element>,
+}
+
+and element = {
+  // Node
+  ...readOnlyNode<node, document, element>,
+  // Element
+  childElementCount: int,
+  children: htmlCollection<element>,
+  clientHeight: int,
+  clientLeft: int,
+  clientTop: int,
+  clientWidth: int,
+  firstElementChild: Js.Null.t<element>,
+  id: string,
+  lastElementChild: Js.Null.t<element>,
+  nextElementSibling: Js.Null.t<element>,
+  previousElementSibling: Js.Null.t<element>,
+  scrollHeight: int,
+  scrollLeft: int,
+  scrollTop: int,
+  scrollWidth: int,
+  tagName: string,
+  // HTMLElement
+  offsetHeight: int,
+  offsetLeft: int,
+  offsetTop: int,
+  offsetWidth: int,
+  offsetParent: Js.Null.t<element>,
+}
+
+and text = {
+  // Node
+  ...readOnlyNode<node, document, element>,
+  // CharacterData
+  data: string,
+  length: int,
+  nextElementSibling: Js.Null.t<element>,
+  previousElementSibling: Js.Null.t<element>,
+}
+
+and document = {
+  ...readOnlyNode<node, document, element>,
+  childElementCount: int,
+  children: htmlCollection<element>,
+  documentElement: element,
+  firstElementChild: Js.Null.t<element>,
+  lastElementChild: Js.Null.t<element>,
+}
+
+module NodeList = {
+  @send
+  external item: (nodeList<'node>, int) => Js.Null.t<'node> = "item"
+}
+
+module HTMLCollection = {
+  @send
+  external item: (htmlCollection<'element>, int) => Js.Null.t<'element> = "item"
+
+  @send
+  external namedItem: (htmlCollection<'element>, string) => Js.Null.t<'element> = "namedItem"
+}
+
+module Node = {
+  module Impl = (
+    T: {
+      type t
+    },
+  ) => {
+    external asNode: T.t => node = "%identity"
+
+    @send
+    external compareDocumentPosition: (T.t, node) => int = "compareDocumentPosition"
+    @send external contains: (T.t, node) => bool = "contains"
+    @send external getRootNode: T.t => node = "getRootNode"
+    @send external hasChildNodes: T.t => bool = "hasChildNodes"
+  }
+
+  include Impl({
+    type t = node
+  })
+}
+
+module Element = {
+  module Impl = (
+    T: {
+      type t
+    },
+  ) => {
+    include Node.Impl({
+      type t = T.t
+    })
+
+    @send
+    external getBoundingClientRect: T.t => Rect.t = "getBoundingClientRect"
+    @send
+    external hasPointerCapture: (T.t, int) => bool = "hasPointerCapture"
+    @send
+    external releasePointerCapture: (T.t, int) => unit = "releasePointerCapture"
+    @send
+    external setPointerCapture: (T.t, int) => unit = "setPointerCapture"
+    @send external focus: T.t => unit = "focus"
+    @send external blur: T.t => unit = "blur"
+
+    @send external setNativeProps: (T.t, {..}) => unit = "setNativeProps"
+  }
+
+  include Impl({
+    type t = element
+  })
+}
+
+module Document = {
+  include Node.Impl({
+    type t = document
+  })
+
+  @send external getElementById: (document, string) => Js.Null.t<element> = "getElementById"
+}
+
+module Text = {
+  include Node.Impl({
+    type t = text
+  })
+
+  @send external substringData: (text, ~offset: int, ~count: int) => string = "substringData"
+}
+
+module NodeType = {
+  /*
+  Helper for handle NodeType
+  Waiting for this issue :
+  https://github.com/rescript-lang/rescript/issues/8280
+  to use this type for node instead
+
+  @tag("nodeType")
+  type rec node =
+    | @as(1) Element(element)
+    | @as(3) Text(text)
+    | @as(9) Document(document)
+
+  and remove this helper
+ */
+  type t =
+    | Element(element)
+    | Text(text)
+    | Document(document)
+    | Unknown
+
+  let classify = (node: node) =>
+    switch node {
+    | {nodeType: 1} => Element(node->Obj.magic)
+    | {nodeType: 3} => Text(node->Obj.magic)
+    | {nodeType: 9} => Document(node->Obj.magic)
+    | _ => Unknown
+    }
+}