def "dependant data fetchers"() {
        def sdl = """
            type Query {
                channel : Channel
                builds : [Build]
            }
            
            type Channel {
                name : String
            }
            
            type Build {
              status : String
            }
        """
        DataFetcher channelDF = new DataFetcher() {
            @Override
            Object get(DataFetchingEnvironment environment) throws Exception {
                return CompletableFuture.supplyAsync {

                    GraphQLContext context = environment.getGraphQlContext()
                    CountDownLatch latch = context.get("channelDFLatch")

                    // just to demonstrate that we can share global context between sibling DFs
                    context.put("buildInfo", "passed")
                    def value = ["name": "channel1"]
                    latch.countDown()
                    return value
                }
            }
        }

        DataFetcher buildsDF = new DataFetcher() {
            @Override
            Object get(DataFetchingEnvironment environment) throws Exception {
                return CompletableFuture.supplyAsync {
                    GraphQLContext context = environment.getGraphQlContext()
                    CountDownLatch latch = context.get("channelDFLatch")
                    // wait until latch is zero from other DF
                    latch.await()

                    String buildInfo = context.get("buildInfo")

                    def value = [["status": buildInfo]]
                    return value
                }
            }
        }
        RuntimeWiring runtimeWiring = RuntimeWiring.newRuntimeWiring().type(TypeRuntimeWiring.newTypeWiring("Query")
                .dataFetcher("channel", channelDF)
                .dataFetcher("builds", buildsDF))
                .build()
        GraphQL graphQL = TestUtil.graphQL(sdl, runtimeWiring).build()

        String query = "query q { channel { name } builds { status }}"

        Consumer<GraphQLContext.Builder> builderConsumer = { GraphQLContext.Builder builder ->
            builder.put("channelDFLatch", new CountDownLatch(1))
        }

        ExecutionInput executionInput = newExecutionInput()
                .query(query)
                .graphQLContext(builderConsumer)
                .build()

        when:
        def executionResult = graphQL.execute(executionInput)
        then:
        executionResult.errors.isEmpty()
        executionResult.data == [channel: [name: "channel1"], builds: [[status: "passed"]]]


    }