Repository navigation
Expand file tree
/
Copy pathStrings.qll
More file actions
93 lines (84 loc) · 2.58 KB
/
Copy pathStrings.qll
File metadata and controls
93 lines (84 loc) · 2.58 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
/** Provides predicates for working with strings. */
overlay[local?]
module;
private import Numbers
/**
* Gets the result of backslash-escaping newlines, carriage-returns, backslashes, and unicode characters in `s`.
*/
bindingset[s]
string escape(string s) {
result =
escapeUnicodeString(s.replaceAll("\\", "\\\\")
.replaceAll("\n", "\\n")
.replaceAll("\r", "\\r")
.replaceAll("\t", "\\t"))
}
/**
* Gets a string where the unicode characters in `s` have been escaped.
*/
bindingset[s]
private string escapeUnicodeString(string s) {
result =
concat(int i, string char |
char = escapeUnicodeChar(s.codePointAt(i).toUnicode())
|
char order by i
)
}
/**
* Gets a unicode escaped string for `char`.
* If `char` is a printable char, then `char` is returned.
*/
bindingset[char]
private string escapeUnicodeChar(string char) {
if isPrintable(char)
then result = char
else
if exists(to4digitHex(any(int i | i.toUnicode() = char)))
then result = "\\u" + to4digitHex(any(int i | i.toUnicode() = char))
else result = "\\u{" + toHex(any(int i | i.toUnicode() = char)) + "}"
}
/** Holds if `char` is easily printable char, or whitespace. */
private predicate isPrintable(string char) {
exists(asciiPrintable(char))
or
char = "\n\r\t".charAt(_)
}
/**
* Gets the `i`th codepoint in `s`.
* Unpaired surrogates are skipped.
*/
bindingset[s]
string getCodepointAt(string s, int i) {
// codePointAt returns the integer codePoint, so we need to convert to a string.
// codePointAt returns integers for both the high and low end. The invalid strings are filtered out by `toUnicode`, but we need to re-count the index, therefore the rank.
// rank is 1-indexed, so we need to offset for that to make this predicate 0-indexed.
result =
rank[i + 1](string char, int charIndex |
char = s.codePointAt(charIndex).toUnicode()
|
char order by charIndex
)
}
/**
* Gets any unicode character that appears in `s`.
*/
bindingset[s]
string getACodepoint(string s) { result = s.codePointAt(_).toUnicode() }
/**
* Gets the number of unicode codepoints in `s` not counting unpaired surrogates.
*/
bindingset[str]
int getCodepointLength(string str) { result = str.codePointCount(0, str.length()) }
/**
* Gets the ASCII code for `char`.
* Only the easily printable chars are included (so no newline, tab, null, etc).
*/
int asciiPrintable(string char) {
char =
rank[result](string c |
c =
"! \"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\\]^_`abcdefghijklmnopqrstuvwxyz{|}~"
.charAt(_)
)
}