Repository navigation
Expand file tree
/
Copy pathsrc.pro
More file actions
143 lines (130 loc) · 3.5 KB
/
Copy pathsrc.pro
File metadata and controls
143 lines (130 loc) · 3.5 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
TEMPLATE = app
QT += core gui network
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
TARGET = sqlitebrowser
CONFIG += debug_and_release
CONFIG += qt
CONFIG += warn_on
# create a unittest option
CONFIG(unittest) {
CONFIG += qtestlib
HEADERS += tests/testsqlobjects.h tests/TestImport.h
SOURCES += tests/testsqlobjects.cpp tests/TestImport.cpp tests/TestMain.cpp
} else {
SOURCES += main.cpp
}
HEADERS += \
sqlitedb.h \
MainWindow.h \
SQLiteSyntaxHighlighter.h \
CreateIndexDialog.h \
AboutDialog.h \
EditTableDialog.h \
PreferencesDialog.h \
EditDialog.h \
ExportCsvDialog.h \
ImportCsvDialog.h \
sqltextedit.h \
sqlitetypes.h \
csvparser.h \
ExtendedTableWidget.h \
grammar/Sqlite3Lexer.hpp \
grammar/Sqlite3Parser.hpp \
grammar/sqlite3TokenTypes.hpp \
sqlitetablemodel.h \
FilterTableHeader.h \
gen_version.h \
SqlExecutionArea.h \
VacuumDialog.h \
DbStructureModel.h \
Application.h \
sqlite.h \
CipherDialog.h
SOURCES += \
sqlitedb.cpp \
MainWindow.cpp \
SQLiteSyntaxHighlighter.cpp \
CreateIndexDialog.cpp \
EditTableDialog.cpp \
PreferencesDialog.cpp \
AboutDialog.cpp \
EditDialog.cpp \
ExportCsvDialog.cpp \
ImportCsvDialog.cpp \
sqltextedit.cpp \
sqlitetypes.cpp \
csvparser.cpp \
ExtendedTableWidget.cpp \
grammar/Sqlite3Lexer.cpp \
grammar/Sqlite3Parser.cpp \
sqlitetablemodel.cpp \
FilterTableHeader.cpp \
SqlExecutionArea.cpp \
VacuumDialog.cpp \
DbStructureModel.cpp \
Application.cpp \
CipherDialog.cpp
RESOURCES += icons/icons.qrc \
translations/flags/flags.qrc
FORMS += \
MainWindow.ui \
CreateIndexDialog.ui \
AboutDialog.ui \
EditTableDialog.ui \
PreferencesDialog.ui \
EditDialog.ui \
ExportCsvDialog.ui \
ImportCsvDialog.ui \
SqlExecutionArea.ui \
VacuumDialog.ui \
CipherDialog.ui
TRANSLATIONS += \
translations/sqlb_zh.ts \
translations/sqlb_de.ts \
translations/sqlb_fr.ts \
translations/sqlb_ru.ts
CONFIG(sqlcipher) {
QMAKE_CXXFLAGS += -DENABLE_SQLCIPHER
LIBS += -lsqlcipher
} else {
LIBS += -lsqlite3
}
LIBPATH_QHEXEDIT=$$OUT_PWD/../libs/qhexedit
LIBPATH_ANTLR=$$OUT_PWD/../libs/antlr-2.7.7
LIBPATH_QCUSTOMPLOT=$$OUT_PWD/../libs/qcustomplot-source
unix {
LIBS += -ldl
}
os2 {
RC_FILE = os2app.rc
}
win32 {
RC_FILE = winapp.rc
INCLUDEPATH += $$PWD
CONFIG(debug,debug|release) {
LIBPATH_QHEXEDIT = $$LIBPATH_QHEXEDIT/debug
LIBPATH_ANTLR = $$LIBPATH_ANTLR/debug
LIBPATH_QCUSTOMPLOT = $$LIBPATH_QCUSTOMPLOT/debug
}
CONFIG(release,debug|release) {
LIBPATH_QHEXEDIT = $$LIBPATH_QHEXEDIT/release
LIBPATH_ANTLR = $$LIBPATH_ANTLR/release
LIBPATH_QCUSTOMPLOT = $$LIBPATH_QCUSTOMPLOT/release
}
}
mac {
RC_FILE = macapp.icns
INCLUDEPATH += -I/usr/local/include \
-I/usr/local/opt/sqlite/include
LIBS += -L/usr/local/lib \
-L/usr/local/opt/sqlite/lib \
-framework Carbon
QMAKE_INFO_PLIST = app.plist
QMAKE_CXXFLAGS += -DCHECKNEWVERSION
}
UI_DIR = .ui
INCLUDEPATH += $$PWD/../libs/antlr-2.7.7 $$PWD/../libs/qhexedit $$PWD/../libs/qcustomplot-source $$PWD/..
LIBS += -L$$LIBPATH_QHEXEDIT -L$$LIBPATH_ANTLR -L$$LIBPATH_QCUSTOMPLOT -lantlr -lqhexedit -lqcustomplot
DEPENDPATH += $$PWD/../libs/antlr-2.7.7 $$PWD/../libs/qhexedit $$PWD/../libs/qcustomplot-source
# Rules for creating/updating {ts|qm}-files
include(i18n.pri)