-
-
Notifications
You must be signed in to change notification settings - Fork 39
Expand file tree
/
Copy pathObjectManager.mm
More file actions
239 lines (209 loc) · 8.25 KB
/
ObjectManager.mm
File metadata and controls
239 lines (209 loc) · 8.25 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
#include <CoreFoundation/CoreFoundation.h>
#include <sstream>
#include "ObjectManager.h"
#include "DataWrapper.h"
#include "Helpers.h"
#include "Caches.h"
#include "Constants.h"
#include "FFICall.h"
using namespace v8;
using namespace std;
namespace tns {
static Class NSTimerClass = objc_getClass("NSTimer");
void ObjectManager::Init(Isolate* isolate, Local<ObjectTemplate> globalTemplate) {
globalTemplate->Set(tns::ToV8String(isolate, "__releaseNativeCounterpart"), FunctionTemplate::New(isolate, ReleaseNativeCounterpartCallback));
}
std::shared_ptr<Persistent<Value>> ObjectManager::Register(Local<Context> context, const Local<Value> obj) {
Isolate* isolate = context->GetIsolate();
std::shared_ptr<Persistent<Value>> objectHandle = std::make_shared<Persistent<Value>>(isolate, obj);
objectHandle->SetWrapperClassId(Constants::ClassTypes::ObjectManagedValue);
ObjectWeakCallbackState* state = new ObjectWeakCallbackState(objectHandle);
objectHandle->SetWeak(state, FinalizerCallback, WeakCallbackType::kFinalizer);
return objectHandle;
}
void ObjectManager::FinalizerCallback(const WeakCallbackInfo<ObjectWeakCallbackState>& data) {
ObjectWeakCallbackState* state = data.GetParameter();
Isolate* isolate = data.GetIsolate();
Local<Value> value = state->target_->Get(isolate);
bool disposed = ObjectManager::DisposeValue(isolate, value);
if (disposed) {
state->target_->Reset();
delete state;
} else {
state->target_->ClearWeak();
state->target_->SetWeak(state, FinalizerCallback, WeakCallbackType::kFinalizer);
}
}
bool ObjectManager::DisposeValue(Isolate* isolate, Local<Value> value, bool isFinalDisposal) {
if (value.IsEmpty() || value->IsNullOrUndefined() || !value->IsObject()) {
return true;
}
Local<Object> obj = value.As<Object>();
if (obj->InternalFieldCount() > 1 && !isFinalDisposal) {
Local<Value> superValue = obj->GetInternalField(1);
if (!superValue.IsEmpty() && superValue->IsString()) {
// Do not dispose the ObjCWrapper contained in a "super" instance
return true;
}
}
BaseDataWrapper* wrapper = tns::GetValue(isolate, value);
//NSLog(@"dispose %p", wrapper);
if (wrapper == nullptr) {
tns::SetValue(isolate, obj, nullptr);
return true;
}
if (wrapper->IsGcProtected() && !isFinalDisposal) {
return false;
}
std::shared_ptr<Caches> cache = Caches::Get(isolate);
switch (wrapper->Type()) {
case WrapperType::Struct: {
StructWrapper* structWrapper = static_cast<StructWrapper*>(wrapper);
void* data = structWrapper->Data();
std::shared_ptr<Persistent<Value>> poParentStruct = structWrapper->Parent();
if (poParentStruct != nullptr) {
Local<Value> parentStruct = poParentStruct->Get(isolate);
BaseDataWrapper* parentWrapper = tns::GetValue(isolate, parentStruct);
if (parentWrapper != nullptr && parentWrapper->Type() == WrapperType::Struct) {
StructWrapper* parentStructWrapper = static_cast<StructWrapper*>(parentWrapper);
parentStructWrapper->DecrementChildren();
}
} else {
if (structWrapper->ChildCount() == 0) {
std::pair<void*, std::string> key = std::make_pair(data, structWrapper->StructInfo().Name());
cache->StructInstances.erase(key);
std::free(data);
} else {
return false;
}
}
break;
}
case WrapperType::ObjCObject: {
ObjCDataWrapper* objCObjectWrapper = static_cast<ObjCDataWrapper*>(wrapper);
id target = objCObjectWrapper->Data();
if (target != nil) {
cache->Instances.erase(target);
[target release];
}
break;
}
case WrapperType::Block: {
BlockWrapper* blockWrapper = static_cast<BlockWrapper*>(wrapper);
if(!blockWrapper->OwnsBlock()) {
std::free(blockWrapper->Block());
}
break;
}
case WrapperType::Reference: {
ReferenceWrapper* referenceWrapper = static_cast<ReferenceWrapper*>(wrapper);
if (referenceWrapper->Data() != nullptr) {
referenceWrapper->SetData(nullptr);
referenceWrapper->SetEncoding(nullptr);
}
break;
}
case WrapperType::Pointer: {
PointerWrapper* pointerWrapper = static_cast<PointerWrapper*>(wrapper);
if (pointerWrapper->Data() != nullptr) {
cache->PointerInstances.erase(pointerWrapper->Data());
if (pointerWrapper->IsAdopted()) {
std::free(pointerWrapper->Data());
pointerWrapper->SetData(nullptr);
}
}
break;
}
case WrapperType::FunctionReference: {
FunctionReferenceWrapper* funcWrapper = static_cast<FunctionReferenceWrapper*>(wrapper);
std::shared_ptr<Persistent<Value>> func = funcWrapper->Function();
if (func != nullptr) {
func->Reset();
}
break;
}
case WrapperType::AnonymousFunction: {
break;
}
case WrapperType::ExtVector: {
ExtVectorWrapper* extVectorWrapper = static_cast<ExtVectorWrapper*>(wrapper);
FFICall::DisposeFFIType(extVectorWrapper->FFIType(), extVectorWrapper->TypeEncoding());
void* data = extVectorWrapper->Data();
if (data) {
std::free(data);
}
break;
}
case WrapperType::Worker: {
WorkerWrapper* worker = static_cast<WorkerWrapper*>(wrapper);
if (!worker->isDisposed()) {
// during final disposal, inform the worker it should delete itself
if (isFinalDisposal) {
worker->MakeWeak();
}
return false;
}
break;
}
default:
break;
}
delete wrapper;
wrapper = nullptr;
tns::DeleteValue(isolate, obj);
return true;
}
void ObjectManager::ReleaseNativeCounterpartCallback(const FunctionCallbackInfo<Value>& info) {
Isolate* isolate = info.GetIsolate();
if (info.Length() != 1) {
std::ostringstream errorStream;
errorStream << "Actual arguments count: \"" << info.Length() << "\". Expected: \"1\".";
std::string errorMessage = errorStream.str();
Local<Value> error = Exception::Error(tns::ToV8String(isolate, errorMessage));
isolate->ThrowException(error);
return;
}
Local<Value> value = info[0];
BaseDataWrapper* wrapper = tns::GetValue(isolate, value);
if (wrapper == nullptr) {
std::string arg0 = tns::ToString(isolate, info[0]);
std::ostringstream errorStream;
errorStream << arg0 << " is an object which is not a native wrapper.";
std::string errorMessage = errorStream.str();
Local<Value> error = Exception::Error(tns::ToV8String(isolate, errorMessage));
isolate->ThrowException(error);
return;
}
if (wrapper->Type() != WrapperType::ObjCObject) {
return;
}
ObjCDataWrapper* objcWrapper = static_cast<ObjCDataWrapper*>(wrapper);
id data = objcWrapper->Data();
if (data != nil) {
std::shared_ptr<Caches> cache = Caches::Get(isolate);
auto it = cache->Instances.find(data);
if (it != cache->Instances.end()) {
ObjectWeakCallbackState* state = it->second->ClearWeak<ObjectWeakCallbackState>();
if (state != nullptr) {
delete state;
}
cache->Instances.erase(it);
}
[data dealloc];
delete wrapper;
tns::SetValue(isolate, value.As<Object>(), nullptr);
}
}
bool ObjectManager::IsInstanceOf(id obj, Class clazz) {
return [obj isKindOfClass:clazz];
}
long ObjectManager::GetRetainCount(id obj) {
if (!obj) {
return 0;
}
if (ObjectManager::IsInstanceOf(obj, NSTimerClass)) {
return 0;
}
return CFGetRetainCount(obj);
}
}