package ui {

import blocks.Block;

import uiwidgets.*;

import scratch.ScratchComment;

public class BlockPalette extends ScrollFrameContents {

public const isBlockPalette:Boolean = true;

public function BlockPalette():void {

super();

this.color = 0xE0E0E0;

}

public function handleDrop(obj:*):Boolean {

// Delete blocks and stacks dropped onto the palette.

var app:Scratch = root as Scratch;

var c:ScratchComment = obj as ScratchComment;

if (c) {

c.x = c.y = 20; // postion for undelete

c.deleteComment();

return true;

}

var b:Block = obj as Block;

if (b) {

if ((b.op == Specs.PROCEDURE_DEF) && hasCallers(b, app)) {

DialogBox.notify('Cannot Delete', 'To delete a block definition, first remove all uses of the block.', stage);

return false;

}

if (b.parent) b.parent.removeChild(b);

b.restoreOriginalPosition(); // restore position in case block is undeleted

Scratch.app.runtime.recordForUndelete(b, b.x, b.y, 0, Scratch.app.viewedObj());

app.scriptsPane.saveScripts();

app.updatePalette();

return true;

}

return false;

}

private function hasCallers(def:Block, app:Scratch):Boolean {

var callCount:int;

for each (var stack:Block in app.viewedObj().scripts) {

// for each block in stack

stack.allBlocksDo(function (b:Block):void {

if ((b.op == Specs.CALL) && (b.spec == def.spec)) callCount++;

});

}

return callCount > 0;

}

public static function strings():Array {

return ['Cannot Delete', 'To delete a block definition, first remove all uses of the block.'];

}

}}